Know-how für Kreative.

Inhaltsverzeichnis
Vorwort
1 Flash für ActionScript
2 ActionScript in Flash
3 Flash Pro für ActionScript
4 Grundlagen der Programmierung
5 Einfache Filmsteuerung
6 Bildschirme und Präsentationen
7 Drucken und das Kontextmenü
8 Textfelder
9 Tasten
10 Datum und Zeit
11 Rechnen
12 Farbe wechseln und Drag
13 Zeichnen und Zufall
14 Von Mäusen und Duplikaten
15 Kollisionstest
16 Sound
17 Video
18 Externe Filme
19 Vorladen und Player erkennen
20 Formulare und UI-Komponenten
21 Komponenten anpassen
22 Formulare versenden
23 Warenkorb
24 Ausblick auf ActionScript 3
Stichwort
Download: - ZIP, ca. 14,4 MB
Ihre Meinung?
<< zurück | Galileo Design / <openbook> /Einstieg in ActionScript | vor >>
Einstieg in ActionScript von Christian Wenz, Tobias Hauser, Armin Kappler Aktuell zu Flash 8
Einstieg in ActionScript brosch., mit CD und QuickFinder und Referenz 416 S., 24,90 Euro Galileo Design ISBN 978-3-89842-774-6 |
| 8 Textfelder
|  | 8.1 Textfelder und ActionScript
|  | 8.2 Mit Textfeld-Inhalten arbeiten
|  | 8.3 Textfelder formatieren und verändern
|  | 8.4 Textfelder dynamisch erzeugen
## 8.3 Textfelder formatieren und verändern
Ein Topf
Dynamische Textfelder und Eingabetextfelder gelangen in einen Topf, sie sind beide TextField-Objekte. Die Eigenschaft type gibt an, ob es sich um ein dynamisches Textfeld (Wert "dynamic") oder um ein Eingabetextfeld (Wert "input") handelt. Interessanterweise können Sie diese Eigenschaft ändern und so ein Eingabetextfeld in ein dynamisches und umgekehrt verwandeln.
Sie erinnern sich, dass der Variablenname eines dynamischen Textfelds oder eines Eingabetextfelds dazu dient, auf dessen Inhalt zuzugreifen. Der Instanzname erlaubt dagegen den direkten Zugriff auf das Textfeld als solches. Sie kennen das schon aus Ereignisprozeduren für Schaltflächen und MovieClips, die ebenfalls Instanznamen besitzen. All diese Flash-Elemente werden durch ihren Instanznamen zu ActionScript-Objekten. Für sie gibt es eine spezielle Klasse, die beschreibt, welche Möglichkeiten es für ein Textfeld-Objekt gibt: Sie heißt TextField. Entsprechend ist ein Textfeld ein TextField-Objekt, also ein Objekt dieser Klasse. Die Fülle an Eigenschaften und Methoden, die die TextField-Klasse bereithält, ist sehr groß. Sie finden sie im Aktionen-Bedienfeld unter ActionScript 2.0-Klassen • Film • TextField (bzw. Flash MX 2004: Integrierte Klassen • Film • TextField). Wenn Sie den Instanznamen des Textfelds mit der Endung _txt versehen, erhalten Sie außerdem im Aktionen-Bedienfeld Codehinweise mit den Möglichkeiten der TextField-Klasse. Der Zugriff auf eine Eigenschaft oder Methode eines Textfelds ist sehr einfach: Sie geben den Instanznamen an und schreiben die Eigenschaft oder Methode nach einem Punkt dahinter:
    instanzname_txt.backgroundColor
Hier klicken, um das Bild zu vergrößern Abbildung 8.7 Die Klasse TextField enthält alle wichtigen Befehle für Textfelder (1) . Wieder ein Beispiel für die Punktsyntax. So können Sie beispielsweise problemlos die Hintergrundfarbe eines Textfelds ausgeben:
    trace(instanzname_txt.backgroundColor);
Wenn eine Eigenschaft änderbar ist, haben Sie auch die Möglichkeit, einen neuen Wert zuzuweisen:
    instanzname_txt.backgroundColor = 0xFF0000;
Das Textfeld erscheint nun mit rotem Hintergrund. ##### Inhalt des Textfelds
Rahmen und Hintergrund anzeigen
Eine Hintergrundfarbe wird nur angezeigt, wenn Rahmen anzeigen im Eigenschafteninspektor aktiviert ist. Sie können allerdings mit der Eigenschaft background extra den Hintergrund einblenden, indem Sie den Wert der Eigenschaft auf true setzen. Erst dann wird die Hintergrundfarbe sichtbar.
Die Eigenschaft text verdient eine besondere Erwähnung. Sie gestattet Ihnen den Zugriff auf den Inhalt des Textfelds. Die folgende Zeile:
    instanzname_txt.text
entspricht also dem direkten Zugriff auf den Variablennamen:
    variablenname_str
Der einzige Unterschied zwischen beiden Varianten: Beim Zugriff mit der Eigenschaft text wird HTML-Inhalt ignoriert und als normaler Text ausgegeben. Um HTML-Inhalt zu bekommen, gibt es die Eigenschaft htmlText. Sie fragen berechtigterweise, welche der beiden Methoden sinnvoller ist. Gebräuchlicher ist die Variante mit dem Variablennamen. Zum einen ist sie älter, da es die Eigenschaften text und htmlText erst seit Flash MX gibt. Zum anderen ist sie einfacher: Der Variablenname erlaubt den direkten Zugriff auf den Inhalt. Die Zuweisung von Werten und Auslesen funktioniert wie bei einer normalen Variablen komplett ohne Punktsyntax. Die Eigenschaften verfolgen dagegen den objektorientierten Ansatz von Flash konsequent. ##### Textfelder = MovieClip? Wenn Sie den Instanznamen eines dynamischen Textfelds oder Eingabetextfelds mit der Endung _txt versehen, erscheinen die Codehinweise im Aktionen-Bedienfeld. Dort finden Sie Eigenschaften wie _visible, _width und _height, die normalerweise ein MovieClip besitzt. In Flash MX erscheinen bei einem Textfeld mit der Endung _txt in den Codehinweisen nicht die Eigenschaften für MovieClips wie _visible etc. Sie können sie allerdings trotzdem verwenden. ##### Äußere Erscheinung Die Optionen, die Ihnen der Eigenschafteninspektor für ein dynamisches Textfeld oder Eingabetextfeld bietet, finden Sie zum Teil auch als Eigenschaften des TextField-Objekts wieder. In vielen Teilen gehen die ActionScript-Möglichkeiten allerdings über den Eigenschafteninspektor hinaus. Tabelle 8.1 auf Seite 164 zeigt Ihnen die wichtigsten Eigenschaften für das äußere Erscheinungsbild eines Textfelds. ##### Text formatieren Die innere Erscheinung, das heißt das Aussehen des Textes, steuern Sie ein wenig anders. Hierfür gibt es zwar auch Eigenschaften wie textColor für die Textfarbe, textHeight für die Höhe und textWidth für die Breite des Textes; die eigentliche Formatierung geschieht aber mit dem TextFormat-Objekt. Dieses Objekt besitzt eine Vielzahl an Eigenschaften, um Text zu formatieren: Von kursiver Schrift (italic) bis zu verschiedenen Textgrößen (size) ist alles möglich. Sie finden die Eigenschaften im Aktionen-Bedienfeld unter ActionScript 2.0-Klassen • Film • TextField (bzw. Flash MX 2004: Integrierte Klassen • Film • TextField). Hier klicken, um das Bild zu vergrößern Hier klicken, um das Bild zu vergrößern Hier klicken, um das Bild zu vergrößern Abbildung 8.8 Die Optionen im Eigenschafteninspektor für dynamisches Textfeld und Eingabetextfeld (Erklärung siehe nächste Seite)
Eigenschaft | Option | Beschreibung | Beispiel (textfeld_ aussehen.fla)
antiAliasingType | (1) | Gibt an, ob das Antialiasing aus dem Flash-Player 7 (normal) oder das verbesserte aus dem Flash-Player 8 zum Einsatz kommt (advanced). Die Einstellung ist neu in Flash 8. | textfeld_txt. anti AliasType = "advanced";
background |  | Wahrheitswert, der angibt, ob das Textfeld einen Hintergrund hat (true) oder nicht (false) | textfeld_txt.background = true;
backgroundColor |  | Hintergrundfarbe des Textfelds als hexadezimaler Wert. Die Hintergrundfarbe wirkt natürlich nur, wenn der Hintergrund des Textfelds mit background eingeblendet ist. | textfeld_txt.border = true; textfeld_txt.backgroundColor = 0xFF0000;
border | (2) Erzeugt Rahmen und Hintergrund | Blendet einen Rahmen um das Textfeld ein (true) oder aus (false). | textfeld_txt.border = true;
borderColor |  | Gibt die Rahmenfarbe als hexadezimalen Wert an, wenn er eingeblendet ist. | textfeld_txt.border = true; textfeld_txt.borderColor = 0xFF0000;
html | (3) | Gibt an, ob Text als HTML ausgegeben wird (true) oder nicht (false). | textfeld_txt.html = true;
multiline | (4) | Erzeugt bei true ein mehrzeiliges Textfeld, false steht für ein einzeiliges. Be- stehende Zeilen werden davon nicht beeinträchtigt. | textfeld_txt.multiline = false;
password | Kennwort | Macht ein Eingabetextfeld zu einem Passwort-Feld (true). Die Eingaben des Nutzers sind nur als Sternchen sichtbar. | textfeld_txt.password = true;
selectable | (5) | Text im Textfeld ist auswählbar (true). Mit false wird der Text ignoriert und der Nutzer kann das darunter liegende Element anklicken. | textfeld_txt.selectable = true;
wordWrap |  | Bricht den Text automatisch um (true) oder nicht (false). | textfeld_txt.wordWrap = false;
Tabelle 8.1 Eigenschaften, um das Äußere von Textfeldern zu ändern In Flash 8 sind noch zwei Eigenschaften hinzugekommen: letterSpacing steuert den Buchstabenabstand und kerning aktiviert die automatisierte Unterschneidung. Eine vollständige Übersicht finden Sie wie gewohnt im Aktionen-Bedienfeld, eine referenzartige Übersicht erhalten Sie in der Hilfe. Hier klicken, um das Bild zu vergrößern Abbildung 8.9 Die Eigenschaften (1) des TextFormat-Objekts im Aktionen-Bedienfeld, darunter etwa kursiver Schnitt (2) und Schriftgröße (3) . Wie sollen Sie aber die Formatierungen auf das Textfeld anwenden? Hier helfen Ihnen einige Methoden des TextField-Objekts. Diese Methoden binden ein TextFormat-Objekt an das jeweilige Textfeld. Folgendermaßen gehen Sie vor:
1. | Zuerst instanziieren Sie ein neues TextFormat-Objekt. Die Endung _fmt am Variablennamen blendet Codehinweise für das TextFormat-Objekt ein.
>     var format_fmt:TextFormat = new TextFormat();
2. | Anschließend belegen Sie Eigenschaften des TextFormat-Objekts mit Werten.
>     format_fmt.bold = false;
>     format_fmt.size = 10;
3. | Nun weisen Sie mit der Methode setTextFormat(TextFormat-Objekt) dem Textfeld das gerade erstellte Textformat zu:
>     textfeld_txt.setTextFormat(format_fmt);
4. | Wenn Sie das TextFormat-Objekt nach dem Zuweisen nicht mehr benötigen, sollten Sie es löschen, um den Hauptspeicher freizugeben:delete (Anweisung)
>     delete format_fmt;
Die oben beschriebene Vorgehensweise ändert sich nicht, allerdings gibt es eine Vielzahl an Varianten. So haben Sie beispielsweise die Möglichkeit, gleich Parameter beim Instanziieren anzugeben:
    var format_fmt:TextFormat = new TextFormat("Arial", 10, 0x660000);
Die Reihenfolge der Parameter ist vorgegeben:
    TextFormat(font, size, color, bold, italic, underline, url, target, align,
    leftMargin, rightMargin, indent, leading);
Hier klicken, um das Bild zu vergrößern Abbildung 8.10 Der Text erscheint in der Schriftgröße 10 Punkt und nicht fett.
Index
Der Index für die einzelnen Zeichen eines Textes beginnt, genau wie bei einem Array, mit der 0. Das heißt, der erste Buchstabe trägt den Index 0.
Das Textformat lässt sich auch nur für Teile einer Zeichenkette setzen. Dazu geben Sie als Parameter den Index eines Buchstabens oder einen Start- und einen Endpunkt an: setTextFormat(Index, TextFormat-Objekt) oder setTextFormat(Startindex, Endindex, TextFormat-Objekt). Der folgende Code ändert also das Format der ersten neun Buchstaben, da der End-Index ausgeschlossen wird:
    textfeld_txt.setTextFormat(0, 9, format_fmt);
Wenn Sie den Inhalt eines Textfelds mit ActionScript ändern (beispielsweise mit der Methode replaceText()), müssen Sie statt setTextFormat() die Methode setNewTextFormat() einsetzen. Soweit die wichtigsten Varianten. Die Unzahl der Eigenschaften und Möglichkeiten erforschen Sie am besten im Aktionen-Bedienfeld und durch viel Testen. ##### Style Sheets Die komfortabelste Art Textfelder zu formatieren, bieten Style Sheets. Sie kennen Style Sheets vielleicht schon als Bestandteil von Webseiten. Dort kommt die Style Sheet-Sprache CSS (Cascading Style Sheets) zum Einsatz. Da CSS ein offizieller Standard des W3C (World Wide Web Consortium) ist, hielt es Macromedia für gut, CSS zur Formatierung von Textfeldern einzusetzen. Deswegen unterstützt Flash seit der Version MX 2004 Style Sheets. Ein Style Sheet ist ein Objekt, das so genannte StyleSheet-Objekt. Sie finden die zugehörige Klasse im Aktionen-Bedienfeld unter Integrierte Klassen • Film • TextField • StyleSheet. Diese Klasse ist also der Klasse TextField untergeordnet. Die Zuweisung eines StyleSheet-Objekts erfolgt etwas anders als beim TextFormat–Objekt, das Sie aus dem letzten Abschnitt kennen. Da die Klasse StyleSheet der Klasse TextField untergeordnet ist, muss sie auch mit dieser Klasse adressiert werden. Ein neues Objekt zu instanziieren, sieht folgendermaßen aus: Hier klicken, um das Bild zu vergrößern Abbildung 8.11 Das StyleSheet-Objekt im Aktionen-Bedienfeld
    var stil:TextField.StyleSheet = new TextField.StyleSheet();
Dieses Objekt muss nun gefüllt werden. Dazu gibt es zwei Alternativen:
1. | Sie verwenden ein externes Style Sheet und laden es mit der Methode load(URL)load() (Methode); allerdings dauert das Laden einige Zeit. Sie sollten das Style Sheet in einem Schlüsselbild laden und erst in einem anderen Schlüsselbild einsetzen. Das Style Sheet selbst enthält
>     stil.load("stile.css");
2. | Sie erstellen selbst mit der Methode setStyle(Stilname, {Stil-Anweisungen})setStyle() (Methode) eigene Stile. Damit der Stilname ein in CSS gängiger Klassenname wird, versehen Sie ihn mit einem Punkt davor.
>     stil.setStyle(".stilname", {color: 0xFF0000, fontSize: '18px',
>     fontStyle: 'italic'});
3. | Vorsicht, die Syntax der Stilanweisungen unterscheidet sich von der einer normalen CSS-Datei (die Sie beispielsweise bei load() verwenden). Zusammengesetzte Stilbefehle werden nicht mit Bindestrich (-), sondern zusammen geschrieben, der zweite Teil beginnt dabei groß. Die einzelnen Stilanweisungen werden mit Kommas voneinander getrennt.
Namensendung
Die Endung des Variablennamens hat bei einem StyleSheet-Objekt keine Bedeutung. Oft wird zwar _css verwendet, aber auch damit erhalten Sie keine Codehinweise. Der schnellste Weg zu Codehinweisen ist also die strenge Typisierung in Flash MX 2004. Alle, die ohne strenge Typisierung arbeiten möchten, können _css allerdings einfach in der Datei AsCodeHints.xml ergänzen (siehe Kapitel 4, »Grundlagen der Programmierung«).
Nun geht es an den Einsatz des Style Sheets. Dem Textfeld weisen Sie das StyleSheet-Objekt mit der Eigenschaft styleSheet zu. Die Eigenschaft beginnt mit kleinem s, die Unterklasse für ein Style Sheet mit großem S.
    textfeld_txt.styleSheet = stil;
Das reicht aber noch nicht. Der Text wird nur dann formatiert, wenn das CSS zugewiesen ist. Der Schlüssel hierzu ist HTML: Sie müssen HTML-Tags in das Textfeld einfügen und über Attribute den Stil aufrufen. Voraussetzung ist, dass die Option Text als HTML wiedergeben im Eigenschafteninspektor aktiviert ist beziehungsweise die korrespondierende Eigenschaft html des TextField-Objekts den Wert true hat. Zum Einfügen des HTML-Textes dient dann die Eigenschaft htmlText des TextField-Objekts:
    textfeld_txt.htmlText =
    "<span class='stilname'>Textfeld mit Beispieltext</span>";
Wie Sie sehen, wird hier in ein <span>-Tag, das selbst keine Layout-Funktion hat, die Stilklasse stilname eingefügt. ##### Text scrollen Normalerweise zeigt ein Textfeld den kompletten Text an, den Sie in Flash eingeben. Was aber, wenn Sie dem Nutzer eine Scrollmöglichkeit einrichten möchten? Dafür gibt es verschiedene Möglichkeiten:
1. | Sie können die UI-Komponente TextArea einsetzen. Sie zeigt automatisch Scrollbalken, wenn zu viel Text enthalten ist.
Hier klicken, um das Bild zu vergrößern Abbildung 8.12 Die TextArea-Komponente mit Scrollbalken
2. | Sie weisen einem dynamischen Textfeld oder einem Eingabetextfeld den Befehl Rollbar zu. Diesen Befehl finden Sie entweder im Menü Text oder im Kontextmenü des Textfelds. Ganz schnell geht es, wenn Sie bei gedrückter (ª)-Taste auf das weiße Rechteck rechts unten im Textfeld doppelklicken. Ist das Textfeld rollbar, wird das weiße Rechteck schwarz und Sie können seine Größe unabhängig vom Inhalt skalieren.
Hier klicken, um das Bild zu vergrößern (1) Abbildung 8.13 Das schwarze Rechteck (1) zeigt, dass es sich um ein rollbares Textfeld handelt. Wenn Sie die zweite Möglichkeit wählen und mit einem rollbaren (auch scrollbaren) dynamischen Textfeld oder Eingabetextfeld arbeiten, wollen Sie sicherlich Schaltflächen hinzufügen, um dem Nutzer das Scrollen im Textfeld zu erlauben. In diesem Fall können Sie mit der Eigenschaft scroll des TextField-Objekts die Scrollposition des Textes verändern. Ein Beispiel hierzu finden Sie auf der CD-ROM: Die Datei textfeld_scrollen.fla (in den Ordnern Flash8, FlashMX2004 und FlashMX) besteht aus einem rollbaren dynamischen Textfeld und zwei Schaltflächen-Symbolen (nachOben_btn und nachUnten_btn). Diese Schaltflächen sollen nun auf Knopfdruck nach oben und nach unten scrollen. Sehen Sie sich zuerst die Ereignisprozedur für die Nach-oben-Schaltfläche an, die im ersten Schlüsselbild des Hauptfilms landet: nachOben_btn.onPress = function() { textfeld_txt.scroll--; } Was passiert? Wenn der Nutzer die Schaltfläche drückt, ändert sich die aktuelle Scrollposition des Textfelds (textfeld_txt.scroll) in die Scrollposition minus 1. Dies verrät einiges über die Scrollposition: Sie beginnt bei 1 (bzw. 0, wenn kein Scrollen möglich ist); wenn ganz nach oben gescrollt ist, hat der Code keine Wirkung mehr, negative Scrollpositionen sind nicht möglich.
Inkrement und Dekrement
Sie sehen hier ein Einsatzgebiet für Inkrement und Dekrement. Mehr dazu in Kapitel 4, »Grundlagen der Programmierung«.
Der Code für die Nach-unten-Schaltfläche sieht ähnlich aus: nachUnten_btn.onPress = function() { textfeld_txt.scroll++; } Es stellt sich die Frage, was passiert, wenn im Textfeld ganz nach unten gescrollt ist. Diese letzte Scrollposition wird in der Eigenschaft maxscroll gespeichert. Sie können sie auslesen, allerdings ist eine Überprüfung beim Scrollen nicht notwendig, da ActionScript automatisch bei der letzen Scrollposition aufhört weiterzuscrollen.
Horizontale
Zum horizontalen Scrollen bietet die TextField-Klasse ebenfalls zwei Eigenschaften: hscroll und maxhscroll. Der Einsatz funktioniert genau wie beim vertikalen Scrollen.
Bis jetzt ist das Scrollen noch ein wenig unpraktisch: Der Nutzer muss immer klicken, um eine Scrollposition weiter zu kommen. In der Praxis wird oft ein anderes Verfahren gewählt: Der Nutzer fährt über den Pfeil nach unten oder oben und der Text scrollt, solange die Maus auf dem Pfeil bleibt. Die Ausgangssituation ist die gleiche wie für das einfachere Beispiel textfeld_scrollen.fla. Hier klicken, um das Bild zu vergrößern Hier klicken, um das Bild zu vergrößern Abbildung 8.14 Auf Klick geht es eine Scrollposition nach unten. Bevor Sie die einzelnen Schritte anschauen und nachvollziehen, gönnen Sie sich einen kurzen Moment der Überlegung. Wie könnte dieses automatische Scrollen realisiert werden? Klar ist, dass Sie andere Ereignisse benötigen: rollOver beim Überfahren der Schaltfläche und rollOut beim Verlassen. Der schwierige Schritt besteht darin, immer weiter zu scrollen, während der Nutzer auf der Schaltfläche verweilt. Hierfür gibt es in ActionScript eine Funktion, die Ihnen hilft: setInterval(Funktionsname, Interval, Parameter). setInterval() ist die grundlegende Funktion, um mit ActionScript zu animieren. Sie werden dieser Funktion im Buch noch öfter begegnen. Vor allem Teil IV, »Animieren«, zeigt Ihnen viele Beispiele. Eine einführende Erklärung finden Sie in Kapitel 13, »Zeichnen und Zufall«. Die Funktion ruft eine von Ihnen erstellte Funktion auf (Funktionsname ohne runde Klammern!), und zwar in festgelegten Abständen (Interval, angegeben in Millisekunden). Optional können Sie Parameter übergeben. setInterval() besitzt einen Rückgabewert, eine numerische ID. Diese ID können Sie in einer Variablen speichern und anschließend mit der Funktion clearInterval(ID) verwenden, um die Funktionsaufrufe wieder zu löschen. ##### Schritt für Schritt: Text beständig scrollen Mit diesem Rüstzeug lösen Sie das Problem: Der komplette Code landet – dank Ereignisprozeduren – innerhalb des ersten Schlüsselbildes im Hauptfilm. Deklarieren Sie eine Variable, die später die ID des Intervalls aufnehmen soll:
    var id_num:Number;
Die Nach-oben-Schaltfläche enthält Anweisungen für zwei Ereignisse: Bei RollOver, wenn der Nutzer mit der Maus darüber fährt, startet ein Intervall, das die Funktion rauf() alle 100 Millisekunden aufruft:
    nachOben_btn.onRollOver = function() {
       id_num = setInterval(rauf, 100);
    }
Verlässt der Nutzer die Schaltfläche mit der Maus (RollOut), wird das Intervall gelöscht:
    nachOben_btn.onRollOut = function() {
       clearInterval(id_num);
    }
Die Nach-Unten-Schaltfläche funktioniert analog, nur dass hier die Funktion runter() aufgerufen wird. Fügen Sie deswegen folgenden Code ein:
    nachUnten_btn.onRollOver = function() {
       id_num = setInterval(runter, 100);
    }
    nachUnten_btn.onRollOut = function() {
       clearInterval(id_num);
    }
Tragen Sie den folgenden Code in das erste Schlüsselbild des Hauptfilms ein:
    function rauf() {
       textfeld_txt.scroll--;
    }
Die Funktion rauf() verringert die Scrollposition um 1 und scrollt damit nach oben. Anschließend fügen Sie den Code für die Funktion runter() ein:
    function runter() {
       textfeld_txt.scroll++;
    }
Diese erhöht die Scrollposition um 1 und scrollt damit nach unten. Hier klicken, um das Bild zu vergrößern Hier klicken, um das Bild zu vergrößern Hier klicken, um das Bild zu vergrößern Abbildung 8.15 Das Scrollen funktioniert nun automatisch. Die fertige Datei finden Sie auf der CD-ROM unter dem Namen textfeld_scrollen_staendig_ AS2.fla im Ordner Flash8 bzw. FlashMX2004 und unter textfeld_scrollen_staendig_AS1.fla im Ordner FlashMX. ### Ihr Kommentar Wie hat Ihnen das <openbook> gefallen? Wir freuen uns immer über Ihre freundlichen und kritischen Rückmeldungen. >> Zum Feedback-Formular
<< zurück | <top> | vor >>
Zum Katalog
ActionScript 3 Das Praxisbuch bestellen
Ihre Meinung?
Wie hat Ihnen das <openbook> gefallen? Ihre Meinung
Buchtipps
| Adobe Flash CS3
| Flash fast forward
| Dreamweaver CS3
Shopping
Versandkostenfrei bestellen in Deutschland und Österreich Info

Copyright © Galileo Press 2006
Für Ihren privaten Gebrauch dürfen Sie die Online-Version natürlich ausdrucken. Ansonsten unterliegt das <openbook> denselben Bestimmungen, wie die gebundene Ausgabe: Das Werk einschließlich aller seiner Teile ist urheberrechtlich geschützt. Alle Rechte vorbehalten einschließlich der Vervielfältigung, Übersetzung, Mikroverfilmung sowie Einspeicherung und Verarbeitung in elektronischen Systemen.

[Galileo Design]
Galileo Press, Rheinwerkallee 4, 53227 Bonn, Tel.: 0228.42150.0, Fax 0228.42150.77, info@galileo-press.de